Gå til innhold
  • Bli medlem
Støtt hjemmeautomasjon.no!

SCRIPT: Fridager.vb - Sjekk for offentlige høytider og andre tilsvarende dager

Moskus

Av Moskus
i Scripts

 Del

Anbefalte innlegg

  • Populært innlegg
Moskus Automatiker

Moskus

Skrevet
  • Populært innlegg
Skrevet

Å vite om det er helg eller ikke er ganske praktisk for hjemmeautomasjon. De aller fleste har andre rutiner i helgene enn de har i ukedagene. Hos oss er derimot rutinene for fridager omtrent prikk lik dager i helgen, så det hadde jo vært praktisk om man istedenfor å sjekke om det er helg, kunne sjekke om det er en fridag.

 

Og nå kan vi det. :)

 

Basert på @xibriz sitt glimrende PHP-script for å sjekke for offentlige høytider (og omskrevet til VB.NET) har jeg lagt til en rutine ekstra, som bl.a. sjekke om det faktisk er helg eller om det er noen andre unntak lagt inn.

 

Du trenger en virtuell device med "Control Use" for Off og On definert (under Status Grapics -> Status-kolonne). Her er min:

Device.png

 

 

Device Ref til denne brukes som parameter i scriptet. Scriptet trigges ved midnatt hver dag for å sjekke om dagen i dager en fridag eller ei.

Event.png

 

 

Fridager.vb 

Sub Main(ByVal deviceReference As String)
        'Moskus 2017
        Dim devRef As Integer = Integer.Parse(deviceReference.ToString)

        Dim isCurrentDateHoliday As Boolean = False
        If Not isCurrentDateHoliday Then isCurrentDateHoliday = IsOfficialHoliday(Now) 'Sjekker offisielle helligdager
        If Not isCurrentDateHoliday Then isCurrentDateHoliday = IsCustomHoliday(Now)   'Sjekker egen-spesifiserte dager

        If isCurrentDateHoliday Then
            hs.CAPIControlHandler(hs.CAPIGetSingleControlByUse(devRef, HomeSeerAPI.ePairControlUse._On))
        Else
            hs.CAPIControlHandler(hs.CAPIGetSingleControlByUse(devRef, HomeSeerAPI.ePairControlUse._Off))
        End If

    End Sub

    Public Function IsCustomHoliday(ByVal _date As Date) As Boolean
        _date = _date.Date 'In case time was added

        'For eksempel sjekkeom det er en lørdag eller søndag
        If _date.DayOfWeek = DayOfWeek.Saturday Then Return True
        If _date.DayOfWeek = DayOfWeek.Sunday Then Return True


        'Jeg har alltid fri i romjulen
        If _date.Month = 12 Then
            If _date.Day >= 27 AndAlso _date.Day <= 31 Then
                Return True
            End If
        End If


        'Andre spesifikke dager kan legges i listen, f.eks. har barnehagen planleggingsdager
        Dim dateList As New System.Collections.Generic.List(Of Date)
        dateList.Add(New Date(2017, 4, 18))

        If dateList.Contains(_date) Then Return True


        'Har vi kommet så langt er det ingen fridager, returner "False"
        Return False
    End Function

    Public Function IsOfficialHoliday(ByVal _date As Date) As Boolean
        'translated php script form xibriz: https://www.diskusjon.no/index.php?showtopic=1084239

        _date = _date.Date 'in case time was added
        Dim easterDate As Date = GetEasterDate(_date.Year)

        'Sjekker om datoen er 1. Januar
        If _date = New Date(_date.Year, 1, 1) Then Return True

        'Sjekker om datoen er pamlesøndag (1. påskedag - 7 dager)
        If _date = easterDate.AddDays(-7) Then Return True

        'Sjekker om datoen er skjærtorsdag (1. påskedag - 3 dager)
        If _date = easterDate.AddDays(-3) Then Return True

        'Sjekker om datoen er langfredag (1. påskedag - 2 dager)
        If _date = easterDate.AddDays(-2) Then Return True

        'Sjekker om datoen er 1. påskedag
        If _date = easterDate Then Return True

        'Sjekker om datoen er 2. påskedag (1. påskedag + 1 dag)
        If _date = easterDate.AddDays(1) Then Return True

        'Sjekker om datoen er 1. mai (offentlig høytidsdag)
        If _date = New Date(_date.Year, 5, 1) Then Return True

        'Sjekker om datoen er 17. mai (grunnlovsdag)
        If _date = New Date(_date.Year, 5, 17) Then Return True

        'Sjekker om datoen er kristi himmelfartsdag (40. påskedag)
        If _date = easterDate.AddDays(39) Then Return True

        'Sjekker om datoen er 1. pinsedag (50. påskedag)
        If _date = easterDate.AddDays(49) Then Return True

        'Sjekker om datoen er 2 pinsedag (51. påskedag)
        If _date = easterDate.AddDays(50) Then Return True

        'Sjekker om datoen er 1. juledag (25. desember)
        If _date = New Date(_date.Year, 12, 25) Then Return True

        'Sjekker om datoen er 2 juledag (26. desember)
        If _date = New Date(_date.Year, 12, 26) Then Return True

        Return False
    End Function

    Public Function GetEasterDate(ByVal Year As Integer) As Date
        'Originally taken from: http://www.thoughtproject.com/Snippets/Easter/Easter.vb.txt

        Dim a As Integer
        Dim b As Integer
        Dim c As Integer
        Dim d As Integer
        Dim e As Integer
        Dim f As Integer
        Dim g As Integer
        Dim h As Integer
        Dim i As Integer
        Dim k As Integer
        Dim l As Integer
        Dim m As Integer
        Dim n As Integer
        Dim p As Integer

        If Year < 1583 Then
            Return Nothing
        Else

            ' Step 1: Divide the year by 19 and store the
            ' remainder in variable A.  Example: If the year
            ' is 2000, then A is initialized to 5.

            a = Year Mod 19

            ' Step 2: Divide the year by 100.  Store the integer
            ' result in B and the remainder in C.

            b = Year \ 100
            c = Year Mod 100

            ' Step 3: Divide B (calculated above).  Store the
            ' integer result in D and the remainder in E.

            d = b \ 4
            e = b Mod 4

            ' Step 4: Divide (b+8)/25 and store the integer
            ' portion of the result in F.

            f = (b + 8) \ 25

            ' Step 5: Divide (b-f+1)/3 and store the integer
            ' portion of the result in G.

            g = (b - f + 1) \ 3

            ' Step 6: Divide (19a+b-d-g+15)/30 and store the
            ' remainder of the result in H.

            h = (19 * a + b - d - g + 15) Mod 30

            ' Step 7: Divide C by 4.  Store the integer result
            ' in I and the remainder in K.

            i = c \ 4
            k = c Mod 4

            ' Step 8: Divide (32+2e+2i-h-k) by 7.  Store the
            ' remainder of the result in L.

            l = (32 + 2 * e + 2 * i - h - k) Mod 7

            ' Step 9: Divide (a + 11h + 22l) by 451 and
            ' store the integer portion of the result in M.

            m = (a + 11 * h + 22 * l) \ 451

            ' Step 10: Divide (h + l - 7m + 114) by 31.  Store
            ' the integer portion of the result in N and the
            ' remainder in P.

            n = (h + l - 7 * m + 114) \ 31
            p = (h + l - 7 * m + 114) Mod 31

            ' At this point p+1 is the day on which Easter falls.
            ' n is 3 for March or 4 for April.

            Return DateSerial(Year, n, p + 1)

        End If

    End Function

 

 

Merk:

Det kan være du vil fjerne noen linjer i scriptet eller i det minste kommentere dem ut. Det er f.eks. ikke sikkert at du har fri uka etter påske: 

        dateList.Add(New Date(2017, 4, 18))

... og hvis ikke, kan du fjerne denne linjen.

 

Det er heller ikke sikkert du har fri romjulen, så da bør du fjerne dette: 

        If _date.Month = 12 Then
            If _date.Day >= 27 AndAlso _date.Day <= 31 Then
                Return True
            End If
        End If

 

Du kan også selvfølgelig legge til dine egne unntak for arbeidsdager hvis du ønsker det. Har du fri hver fredag, så kan du jo bare legge det til. :)

 

 

Jeg har nå byttet ut alle sjekker på om det er helg eller ikke til å sjekke om "Fridag" er på eller ikke. Når jeg tenker meg om tror jeg at jeg skal sette "On" til å være "Fridag" og "Off" til å være "Arbeidsdag". ;) 

 

Som sagt; så gjort:

Device2.png

 

... som da blir slik:

Device3.png

 

 

EDIT: 17. mai var satt til å være 17.01 istedenfor 17.05. Korrigert. ;) 

 

 

Versjon med to devicer, en for dagen i dag og en for dagen i morgen:

Spoiler 

Sub Main(ByVal deviceReference As String)
        '© Moskus 2017
        Dim input() As String = deviceReference.Split(",")
        Dim devRefToday As Integer = Integer.Parse(input(0))
        Dim devRefTomorrow As Integer = Integer.Parse(input(1))

        'Checking today
        Dim isCurrentDateHoliday As Boolean = False
        If Not isCurrentDateHoliday Then isCurrentDateHoliday = IsOfficialHoliday(Now) 'Sjekker offisielle helligdager
        If Not isCurrentDateHoliday Then isCurrentDateHoliday = IsCustomHoliday(Now)   'Sjekker egen-spesifiserte dager

        If isCurrentDateHoliday Then
            hs.CAPIControlHandler(hs.CAPIGetSingleControlByUse(devRefToday, HomeSeerAPI.ePairControlUse._On))
        Else
            hs.CAPIControlHandler(hs.CAPIGetSingleControlByUse(devRefToday, HomeSeerAPI.ePairControlUse._Off))
        End If


        'Checking tomorrow
        Dim isNextDateHoliday As Boolean = False
        If Not isNextDateHoliday Then isNextDateHoliday = IsOfficialHoliday(Now.AddDays(1)) 'Sjekker offisielle helligdager
        If Not isNextDateHoliday Then isNextDateHoliday = IsCustomHoliday(Now.AddDays(1))   'Sjekker egen-spesifiserte dager

        If isNextDateHoliday Then
            hs.CAPIControlHandler(hs.CAPIGetSingleControlByUse(devRefTomorrow, HomeSeerAPI.ePairControlUse._On))
        Else
            hs.CAPIControlHandler(hs.CAPIGetSingleControlByUse(devRefTomorrow, HomeSeerAPI.ePairControlUse._Off))
        End If
    End Sub

Public Function IsCustomHoliday(ByVal _date As Date) As Boolean
    _date = _date.Date 'In case time was added

    'For eksempel sjekkeom det er en lørdag eller søndag
    If _date.DayOfWeek = DayOfWeek.Saturday Then Return True
    If _date.DayOfWeek = DayOfWeek.Sunday Then Return True


    'Jeg har alltid fri i romjulen
    If _date.Month = 12 Then
        If _date.Day >= 24 AndAlso _date.Day <= 31 Then
            Return True
        End If
    End If


    'Andre spesifikke dager kan legges i listen, f.eks. har barnehagen planleggingsdager
    Dim dateList As New System.Collections.Generic.List(Of Date)
    dateList.Add(New Date(2017, 8, 17))
    dateList.Add(New Date(2017, 11, 17))
    dateList.Add(New Date(2017, 12, 22))

    If dateList.Contains(_date) Then Return True

    'Har vi kommet så langt er det ingen fridager, returner "False"
    Return False
End Function

Public Function IsOfficialHoliday(ByVal _date As Date) As Boolean
    'translated php script form xibriz: https://www.diskusjon.no/index.php?showtopic=1084239

    _date = _date.Date 'in case time was added
    Dim easterDate As Date = GetEasterDate(_date.Year)

    'Sjekker om datoen er 1. Januar
    If _date = New Date(_date.Year, 1, 1) Then Return True

    'Sjekker om datoen er pamlesøndag (1. påskedag - 7 dager)
    If _date = easterDate.AddDays(-7) Then Return True

    'Sjekker om datoen er skjærtorsdag (1. påskedag - 3 dager)
    If _date = easterDate.AddDays(-3) Then Return True

    'Sjekker om datoen er langfredag (1. påskedag - 2 dager)
    If _date = easterDate.AddDays(-2) Then Return True

    'Sjekker om datoen er 1. påskedag
    If _date = easterDate Then Return True

    'Sjekker om datoen er 2. påskedag (1. påskedag + 1 dag)
    If _date = easterDate.AddDays(1) Then Return True

    'Sjekker om datoen er 1. mai (offentlig høytidsdag)
    If _date = New Date(_date.Year, 5, 1) Then Return True

    'Sjekker om datoen er 17. mai (grunnlovsdag)
    If _date = New Date(_date.Year, 5, 17) Then Return True

    'Sjekker om datoen er kristi himmelfartsdag (40. påskedag)
    If _date = easterDate.AddDays(39) Then Return True

    'Sjekker om datoen er 1. pinsedag (50. påskedag)
    If _date = easterDate.AddDays(49) Then Return True

    'Sjekker om datoen er 2 pinsedag (51. påskedag)
    If _date = easterDate.AddDays(50) Then Return True

    'Sjekker om datoen er 1. juledag (25. desember)
    If _date = New Date(_date.Year, 12, 25) Then Return True

    'Sjekker om datoen er 2 juledag (26. desember)
    If _date = New Date(_date.Year, 12, 26) Then Return True

    Return False
End Function

Public Function GetEasterDate(ByVal Year As Integer) As Date
    'Originally taken from: http://www.thoughtproject.com/Snippets/Easter/Easter.vb.txt

    Dim a As Integer
    Dim b As Integer
    Dim c As Integer
    Dim d As Integer
    Dim e As Integer
    Dim f As Integer
    Dim g As Integer
    Dim h As Integer
    Dim i As Integer
    Dim k As Integer
    Dim l As Integer
    Dim m As Integer
    Dim n As Integer
    Dim p As Integer

    If Year < 1583 Then
        Return Nothing
    Else

        ' Step 1: Divide the year by 19 and store the
        ' remainder in variable A.  Example: If the year
        ' is 2000, then A is initialized to 5.

        a = Year Mod 19

        ' Step 2: Divide the year by 100.  Store the integer
        ' result in B and the remainder in C.

        b = Year \ 100
        c = Year Mod 100

        ' Step 3: Divide B (calculated above).  Store the
        ' integer result in D and the remainder in E.

        d = b \ 4
        e = b Mod 4

        ' Step 4: Divide (b+8)/25 and store the integer
        ' portion of the result in F.

        f = (b + 8) \ 25

        ' Step 5: Divide (b-f+1)/3 and store the integer
        ' portion of the result in G.

        g = (b - f + 1) \ 3

        ' Step 6: Divide (19a+b-d-g+15)/30 and store the
        ' remainder of the result in H.

        h = (19 * a + b - d - g + 15) Mod 30

        ' Step 7: Divide C by 4.  Store the integer result
        ' in I and the remainder in K.

        i = c \ 4
        k = c Mod 4

        ' Step 8: Divide (32+2e+2i-h-k) by 7.  Store the
        ' remainder of the result in L.

        l = (32 + 2 * e + 2 * i - h - k) Mod 7

        ' Step 9: Divide (a + 11h + 22l) by 451 and
        ' store the integer portion of the result in M.

        m = (a + 11 * h + 22 * l) \ 451

        ' Step 10: Divide (h + l - 7m + 114) by 31.  Store
        ' the integer portion of the result in N and the
        ' remainder in P.

        n = (h + l - 7 * m + 114) \ 31
        p = (h + l - 7 * m + 114) Mod 31

        ' At this point p+1 is the day on which Easter falls.
        ' n is 3 for March or 4 for April.

        Return DateSerial(Year, n, p + 1)

    End If

End Function

 

 

 

  • Like 9
  • Thanks 3
xibriz Kodemaker

xibriz

Skrevet
Skrevet

Det er bra at en av mine første OpenSource-kodesnutter kom til nytte :) Det er ikke alle som vet at det å beregne helligdager i Norge er enkel mattematikk ;)

  • Like 2
Moskus Automatiker

Moskus

Skrevet
  • Forfatter
Skrevet
21 minutter siden, xibriz skrev:

Det er ikke alle som vet at det å beregne helligdager i Norge er enkel mattematikk ;)

Jeg visste ikke... ;) 

  • Haha 1
ZoRaC Blåtannlege

ZoRaC

Skrevet
Skrevet
36 minutter siden, xibriz skrev:

Det er ikke alle som vet at det å beregne helligdager i Norge er enkel mattematikk ;)

 

Hmm... når jeg gikk på skolen så var ikke ligninger med 14 ukjente betegnelsen på "enkel mattematikk"...

Spoiler 

 Public Function GetEasterDate(ByVal Year As Integer) As Date
        'Originally taken from: http://www.thoughtproject.com/Snippets/Easter/Easter.vb.txt

        Dim a As Integer
        Dim b As Integer
        Dim c As Integer
        Dim d As Integer
        Dim e As Integer
        Dim f As Integer
        Dim g As Integer
        Dim h As Integer
        Dim i As Integer
        Dim k As Integer
        Dim l As Integer
        Dim m As Integer
        Dim n As Integer
        Dim p As Integer

        If Year < 1583 Then
            Return Nothing
        Else

            ' Step 1: Divide the year by 19 and store the
            ' remainder in variable A.  Example: If the year
            ' is 2000, then A is initialized to 5.

            a = Year Mod 19

            ' Step 2: Divide the year by 100.  Store the integer
            ' result in B and the remainder in C.

            b = Year \ 100
            c = Year Mod 100

            ' Step 3: Divide B (calculated above).  Store the
            ' integer result in D and the remainder in E.

            d = b \ 4
            e = b Mod 4

            ' Step 4: Divide (b+8)/25 and store the integer
            ' portion of the result in F.

            f = (b + 8) \ 25

            ' Step 5: Divide (b-f+1)/3 and store the integer
            ' portion of the result in G.

            g = (b - f + 1) \ 3

            ' Step 6: Divide (19a+b-d-g+15)/30 and store the
            ' remainder of the result in H.

            h = (19 * a + b - d - g + 15) Mod 30

            ' Step 7: Divide C by 4.  Store the integer result
            ' in I and the remainder in K.

            i = c \ 4
            k = c Mod 4

            ' Step 8: Divide (32+2e+2i-h-k) by 7.  Store the
            ' remainder of the result in L.

            l = (32 + 2 * e + 2 * i - h - k) Mod 7

            ' Step 9: Divide (a + 11h + 22l) by 451 and
            ' store the integer portion of the result in M.

            m = (a + 11 * h + 22 * l) \ 451

            ' Step 10: Divide (h + l - 7m + 114) by 31.  Store
            ' the integer portion of the result in N and the
            ' remainder in P.

            n = (h + l - 7 * m + 114) \ 31
            p = (h + l - 7 * m + 114) Mod 31

            ' At this point p+1 is the day on which Easter falls.
            ' n is 3 for March or 4 for April.

            Return DateSerial(Year, n, p + 1)

        End If

 

... men joda, det ser vel verre ut enn det egentlig er. :) 

Moskus Automatiker

Moskus

Skrevet
  • Forfatter
Skrevet
17 minutter siden, ZoRaC skrev:

Hmm... når jeg gikk på skolen så var ikke ligninger med 14 ukjente betegnelsen på "enkel mattematikk"...

Det er ikke antall ukjente som løses. Alle variablene har jo en kjent løsning.

Verre er det hvis vi måtte kjøre annen analyse på det.

 

Vet heller ikke om jeg ser problemet. Men så liker jeg matte. ;) 

ZoRaC Blåtannlege

ZoRaC

Skrevet
Skrevet
1 time siden, Moskus skrev:

Det er ikke antall ukjente som løses. Alle variablene har jo en kjent løsning.

 

Definisjonsspørsmål... "p" lar seg ikke løse uten "h" og "m", som ikke lar seg løse uten "a", "b", "d" og "g", osv. Før man har regnet ut dem er de jo "ukjent". ;) 

Moskus Automatiker

Moskus

Skrevet
  • Forfatter
Skrevet
16 minutter siden, ZoRaC skrev:

Definisjonsspørsmål...

Nei. ;)

Noen er selvfølgelig avhengig av de andre, men alle har en kjent løsning.

Evelen Kodemaker

Evelen

Skrevet
Skrevet (endret)

Det kunne man.

Startet i gårkveld på et helligdags-script som tar for seg en kalendernettside for å finne ut om det er hellig eller ei.

Viste ikke dette kunne løses matematisk, men jeg akter å fortsette (mest tor gøy).

 

Fordelen med matematikk som her er at man slipper være avhengig av tilgang til en webside og Internett.

Fordelen med å hente info fra en side er at man slipper å ha korrekt dato stilt inn på serveren samt slipper ta høyde for hvorvidt politiske krefter endrer helligdagene.

Ikke at jeg tror noen av de to grunnene er særlig betydelige :P

 

Endret av Evelen
Moskus Automatiker

Moskus

Skrevet
  • Forfatter
Skrevet
2 timer siden, Asterix skrev:

Kunne også potensielt løses med mindre matematikk, med denne? https://webapi.no/api/v1/holydays/2017

Mindre matematikk, riktignok, men mer styr for å tolke det. Tipper at scriptet over vil kreve vesentlig mindre ressurser enn å laste ned en fil og tolke den, og så vurdere om datoen er en hellidag eller ikke (men den totale ressursbruken er neppe avgjørende).

 

Og så er det flere muligheter for feil. Hva om tjenesten flyttes, eller legges ned? Eller rett og slett bare har en dårlig dag? ;) 

Og man må uansett gjøre unntak for sine egne definerte feriedager, da webapi'en kun gir de offentlige høytidene.

Evelen Kodemaker

Evelen

Skrevet
Skrevet (endret)

 

Det kan jo deles opp eventuelt i flere script, eller hendelser. Kanskje ryddigst sånn? 

 

f.eks

if offentlig_helligdag_Script finner helligdag

Set helligdag_device=on, else off

 

if fri_fra_jobben_script finner fri

Set fridag_device=on, else off

 

if helligdag_device or fridag_device = on

set fri_total = on, else off

Endret av Evelen
  • Like 1
Moskus Automatiker

Moskus

Skrevet
  • Forfatter
Skrevet
12 minutter siden, Evelen skrev:

Det kan jo deles opp eventuelt i flere script, eller hendelser.

... så man kan gjøre det enda mer komplisert enn nødvendig? :P 

Evelen Kodemaker

Evelen

Skrevet
Skrevet
1 time siden, Moskus skrev:

... så man kan gjøre det enda mer komplisert enn nødvendig? :P 

øyet som ser det ;) blir vel egentlig bare mindre komplisert slik jeg ser det.

Asterix WAF-maker

Asterix

Skrevet
Skrevet
1 hour ago, Moskus said:

Mindre matematikk, riktignok, men mer styr for å tolke det. Tipper at scriptet over vil kreve vesentlig mindre ressurser enn å laste ned en fil og tolke den, og så vurdere om datoen er en hellidag eller ikke (men den totale ressursbruken er neppe avgjørende).

 

Og så er det flere muligheter for feil. Hva om tjenesten flyttes, eller legges ned? Eller rett og slett bare har en dårlig dag? ;) 

Og man må uansett gjøre unntak for sine egne definerte feriedager, da webapi'en kun gir de offentlige høytidene.

Egentlig om man snakker om å håndtere også andre fridager, så er hardcoding i en script ikke optimal synes jeg. Men det tilbyr en kjapp løsning til problemet, uten tvil.

Ideelt burde enten en script lese en annen kalender (som det var foreslått i samme tråd), eller burde HS ha en kalender som vi kunne forsyne med ferie og andre ting fra api'er eller ikke. 

Har feks en Somfy Tahoma boks, som har en grei måte å håndtere det, som jeg kunne tenke neg å ha i HS; det er en 'vanlig' kalender hvor du kan knytte 'dagstype' til de enkelte dager, feks standard, weekend, ferie, hjemmekontor osv...

Så definerer du hva som skjer i de forskjellige dagstypene. Alt på en grafisk måte (drag&drop). 

Ser at det ligger også noen plugins for å bringe en kalender i HS (feks HiTec), eller bringe innholdet til HS. Kanskje noen har erfaring med dette? ;)

Moskus Automatiker

Moskus

Skrevet
  • Forfatter
Skrevet
9 timer siden, Asterix skrev:

Ideelt burde enten en script lese en annen kalender (som det var foreslått i samme tråd), eller burde HS ha en kalender som vi kunne forsyne med ferie og andre ting fra api'er eller ikke. 

Det er uten tvil det ideelle. "Hardkoding" av fridager (det er nå enkelt å flytte til en ini-fil, hvis du synes det blir mindre "hardkodet" av det ;) ) er i mellomtiden et nødvendig onde, slik jeg ser det.

 

Jeg har lenge hatt en drøm om at HS leser Outlook.com-felleskalenderen vår. Men har foreløpig ikke fått det til.

Asterix WAF-maker

Asterix

Skrevet
Skrevet
11 minutes ago, Moskus said:

 

Jeg har lenge hatt en drøm om at HS leser Outlook.com-felleskalenderen vår. Men har foreløpig ikke fått det til.

Når jeg Googlet litt rundt, fant jeg noe om det (fra han som lagde Tenscripting tror jeg). Men det var antakelig for den gamle versjonen av Outlook?

Moskus Automatiker

Moskus

Skrevet
  • Forfatter
Skrevet

Outlook-versjonenes APIer er relativt like, så det kan godt være det fungerer nå. Mitt problem er imidlertid at det ikke er "default calendar" jeg skal hente informasjon fra, og det var plutselig vanskeligere enn det burde. Men det er mulig jeg som er treig, og ikke har prøvd nok...

  • 2 måneder senere...

Bli med i samtalen

Du kan publisere innhold nå og registrere deg senere. Hvis du har en konto, logg inn nå for å poste med kontoen din.

Gjest
Skriv svar til emnet...

×   Du har limt inn tekst med formatering.   Lim inn uten formatering i stedet

  Du kan kun bruke opp til 75 smilefjes.

×   Lenken din har blitt bygget inn på siden automatisk.   Vis som en ordinær lenke i stedet

×   Tidligere tekst har blitt gjenopprettet.   Tøm tekstverktøy

×   Du kan ikke lime inn bilder direkte. Last opp eller legg inn bilder fra URL.

×
 Del
Gå til emneliste
×
×
  • Opprett ny...

Viktig informasjon

Vi har plassert informasjonskapsler/cookies på din enhet for å gjøre denne siden bedre. Du kan justere dine innstillinger for informasjonskapsler, ellers vil vi anta at dette er ok for deg.