Luftfuktighet i kjeller

[HSv]

Jeg har en kjeller med til tider ganske høy relativ luftfuktighet, så jeg har en luftavfukter som surrer og går der.

 

Og så har jeg tenkt som så - dersom uteluften er tørrere enn kjellerluften så kan jeg jo blåse inn uteluft.

 

Men uteluft og kjellerluft har gjerne forskjellig temperatur. Jeg måler allerede både RH og temperatur både ute og i kjelleren, så nå trenger jeg en formel for å beregne om det lønner seg å blåse inn uteluft, slik at RH i kjelleren synker.

 

Er det noen som kan hjelpe meg med noe slikt?

 

[Moskus]

21 minutter siden, HSv skrev:

Er det noen som kan hjelpe meg med noe slikt?

Helt ærlig tror jeg denne formelen vil fungere utmerket:

Antall_ganger_det_lønner_seg_å_blåse_luft_utenfra_og_inn_mtp_RH = 0

 

Tørk heller luften inne. Det er sannsynligvis langt mer økonomisk enn å varme "tørrere" (hvis det skjer) uteluft til innetemperatur. 

[HSv]

Nå er dette, om ikke akkurat jordkjeller, så ikke så veldig langt unna. Det aller meste av fuktigheten kommer fra gulv og vegger. (Man kan godt si jeg bør utbedre kjeller, men det er ikke tema her) Temperatur i kjeller er jeg heller ikke så opptatt av - om jeg blåser inn kald luft så bekymrer ikke det meg, så lenge det senker luftfuktigheten.

 

Så derfor lurer jeg ennå på om det finnes en formel mer basert på fysikk enn tro ?

[Moskus]

Ah, OK. Det forandrer jo saken litt. Siden det står en luftavfukter der, tenkte jeg at det var snakk om oppholdsrom, iallfall bruksrom.

 

Om det finnes formler for dette er jeg usikker på (det gjør det sikkert hvis du snakker med en RIV-fyr). Har du tilgang til Byggforsk (se f.eks. på 727.121), så finner man mye. Imidlertid er det forholdsvis enkelt med fuktige kjellere: I 9 av 10 tilfeller med for høy fuktighet mangler ventilasjon, evt. også varme for å sørge for at temperaturgradienten går utover.

 

Hvis du har lite gjennomtrekk, så kan det faktisk lønne seg å blåse luft utenfra og inn, men etter det jeg husker fra Bygningsfysikken er det bedre å blåse inneluften ut, istedenfor å ta uteluft og blåse den inn. 

 

Hvor i landet bor du?

Og hvilke RH-verdier har du typisk inne og ute?

 

Jeg bor i Stavanger, og her er jo ofte RH ute høyere enn inne, nesten uansett...

 

 

[HSv]

Jeg bor også i Stavanger - i et gammelt hus på Storhaug. Men selv her har jo Rh utendørs variert mellom 40 og 90% bare de siste 5 ukene.

Så derfor vil jeg kumme mekke sammen en liten vifte av ting jeg har liggende. Viften er oppgitt til å kunne flytte 150 m^3 per time (akkurat det stiller jeg meg litt tvilende til, men dog...)

Men jeg vil ikke kjøre denne viften dersom det fører til at det øker Rh i kjelleren.
Akkurat i dag vil det definitivt ikke hjelpe å blåse inn luft, men på en kald og klar deg vil det nok være til nytte.

[DeVille]

 

 

[Moskus]

3 minutter siden, HSv skrev:

Men selv her har jo Rh utendørs variert mellom 40 og 90% bare de siste 5 ukene.

Det ser jo ut til at høsten har kommet, så jeg tenker at i snitt vil RH_ute > RH_inne.

 

Vi har nettopp begynt å ta i bruk den nye garasjen, og der er det noenlunde samme problemstilling, så jeg er absolutt interessert i temaet. Men jeg tenker uansett å trekke luften ut, istedenfor å ta uteluft aktivt inn.

Foreløpig skal jeg bare logge nivåene over tid, og sjekke om det er enkelte hendelser jeg må ta hensyn til.

 

Har du logg for dine RH-verdier? Hadde vært spennende å sett.

[HSv]

Glimrende - Takk ?

Akkurat noe slikt jeg var på utkikk etter ?

[HSv]

5 minutter siden, Moskus skrev:

Har du logg for dine RH-verdier? Hadde vært spennende å sett.

Ja, jeg har logg fra Device History fra en spesifikk sensor tilbake til 21 jan i år. Men jeg har ikke særlig tiltro til målinger av Rh fra kun en sensor.

 

Men siden 21. aug så beregner jeg snittet fra 4-5 forskjellige målere (et par multisensor - min egen og naboers Netatmo), og de har jeg mer tro på.

 

Skal se om jeg får det over i et excel-ark.

[Moskus]

Det hadde vært gøy å sett. Jeg har begynt logging selv nettopp for jeg har ikke hatt bruk for det før nå, men ikke kommet særlig langt. Værstasjonen min (riktignok kun en sensor, men det er årevis med data der) viser i snitt forholdsvis høye RH-verdier...

[Gjelsvik]

Samme problemstilling her. Om man dytter inneluften ut, eller suger uteluften inn vil i det store og det hele ikke ha noe å si.

Luften man skifter ut vil komme utenifra uansett.

 

Er interessert i å høre hvilke sensorer dere bruker? Jeg har brukt røykvarslere fra verisure, men de oppdaterer seg så sjeldenm, typ 1 gang i døgnet. Så er interessert i noe som er litt mer høyoppløst.

[Moskus]

2 minutter siden, Gjelsvik skrev:

Om man dytter inneluften ut, eller suger uteluften inn vil i det store og det hele ikke ha noe å si.

Luften man skifter ut vil komme utenifra uansett.

Jo det er det, hvis jeg skal tro bygningsfysikeren på kontoret (for jeg måtte jo spørre).

 

3 minutter siden, Gjelsvik skrev:

Er interessert i å høre hvilke sensorer dere bruker?

Både Multisensor og Viking/OregonScientific på 433 MHz.

[HSv]

 

6 minutter siden, Gjelsvik skrev:

Er interessert i å høre hvilke sensorer dere bruker?

I kjelleren bruker jeg et par gamle multisensor 5, samt noen billige 433 MHz sensorer.

Ute har jeg et par multisensor 6, pluss min egen Netatmo, samt noen Netatmo'er i nabolaget.

Jeg kjører et skript som beregner gjennomsnitt av disse sensorene, og skriver verdien tilbake til virtuelle sensorer i HomeSeer

 

Nå har jeg kjøpt en haug med Aqara  zigbee sensorer fra Kina, og flere er på vei, og noen av disse kommer nok til å bli satt ned i kjelleren også.

[Gjelsvik]

433mhz er ute av huset her for en stund siden.. Mulig jeg finner igjen den gamle rfxlan boksen jeg kjøpte for et tiår siden, men jeg tviler.

 

Om du blåser inneluften ut så skaper du et undertrykk, og friskluftsventilene i kjelleren vil tilføre kald luft utenifra.

Motsatt så vil du skape et overtrykk, og inneluften blir dyttet ut i de samme ventilene. Jeg vil i allefall tenke at mengden luft man skifter ut vil være den samme. 

 

Det er godt mulig det i praksis vil være store lokale forskjeller (rom for rom) blåser man inn kald uteluft _ett_ sted så blir jo dette rommet veldig nedkjølt. Du får en høyere konsentrasjon med ny luft. Blåser man ut luften, så vil man fordele tilluft i de tilgjengelige ventiler/sprekker, utette vinduer etc som finnes, og sannsynligvis få mindre temperaturforskjell i rommet der viften står.

[HSv]

Da har jeg et script som fungerer for min del, og deler det her i tilfelle andre trenger noe lignende (...og bare etter noen timer viser det ganske overraskende resultater...)
Jeg regner ut duggpunkt innendørs og utendørs, og dersom DP ute er lavere enn DP inne så skrives dette til et virtuelt device (dette må du lage selv først)
Basert på dette virtuelle devicet kan jeg stoppe / starte en vifte.

Testet på Ubuntu 18.04 & HomeSeer 3

Så kan det bli spennende å se om denne viften faktisk har noen innvirkning på Rh i kjellern min ? 

 

Kommentarer er som alltid velkomne ?

 

Så altså -

- Lag deg en (ReadOnly) virtual device

- Kopier scriptet til der du ønsker det, og sett rettigheter.

- Endre scriptet slik at du bruker riktig dev ID på input devicene dine (4 stk - Temp inne og ute, Rh inne og ute)

- Lag deg en evnt, med det nye virual device som parameter

 

For ordens skyld - scriptet er løst basert på / inspirert av koden funnet i ZoRaC sin tråd nevnt over her.

 

Endret 13. september 2019 av HSv
Slettet v. 1.0 siden det nå ligger en ny og bedre versjon nedenfor :-)

[HSv]

Ny versjon 1.1 - som lar deg logge til en CSV fil om du ønsker å analysere data nærmere.

 

Spoiler

' DewPointCompare.vb, v. 1.1
' Input param: Output device ref ID
' Calculates Dew Point for two locations, based on measured temperatures
' and relative humidity.
' The output could be used to decide if a ventilation fan should start or stop.
'   HSv, Sept. 2019
'
' 1.0 - Initial
' 1.1 - Enabled logging to CSV-file.


Public Module GlobalVars
    Private _infoLog  As Boolean = True ' Log whats happening...?
    Private _warnLog  As Boolean = True ' Log warnings...? (you really should!)
    Private _debugLog As Boolean = True ' Log a bit more...?
    'Private _debugLog As Boolean = False ' Log a bit more...?

    Public ReadOnly Property InfoLog As Boolean
        Get
            Return _infoLog
        End Get
    End Property

    Public ReadOnly Property WarnLog As Boolean
        Get
            Return _warnLog
        End Get
    End Property

    Public ReadOnly Property DebugLog As Boolean
        Get
            Return _debugLog
        End Get
    End Property

End Module


Public Sub Main(ByVal _params As Object)

  ' If you want, you can log data to a CSV-file
  ' Note: You need to create the file yourself, and enter the filename here!
  Dim LogToFile As Boolean = True
  Dim Logfile   As String  = "/usr/local/HomeSeer/Logs/DewpointCompare.log"

  ' Devices holding input measurements:
  Dim TIdev  As Integer = 1033  ' Measured Temp. indoors
  Dim RhIdev As Integer = 1034  ' Measured Rel. Humid. indoors
  Dim TOdev  As Integer = 978   ' Measured Temp. outdoors
  Dim RhOdev As Integer = 2948  ' Measured Rel. Humid. outdoors


  Dim LogID       As String  = "Dew Point"
  Dim statusDev   As Integer = Integer.parse(_params.ToString)
  ' Does the device exist at all...?
  If ( Not hs.DeviceExistsRef(statusDev)) Then
    Logging(LogID, "warn", "Device " & statusDev & " does not exist - Exiting!")
    Exit Sub
  End If

  Dim cA As Double
  Dim cB As Double
  '-----------------------------
  'Values from https://en.wikipedia.org/wiki/Dew_point
  '--(Smarter people than me have found these values - I just pick one,
  '-- and assume one set is as good as the other.)

  ' = Psychrometry and Psychrometric Charts
  'cA = 17.27
  'cB = 237.7

  ' = David Bolton in the Monthly Weather Review
  cA = 17.67
  cB = 243.5

  ' = Sonntag1990
  'cA = 17.62
  'cB = 243.12
  '-----------------------------

  'These algorithms are based on the Magnus-Tetens formula.
  'Calculate dew point temperature using measured air temperature
  'and measured relative humidity.
  'Tested with https://www.omnicalculator.com/physics/dew-point

  Dim TempIndoors  As Double = hs.DeviceValueEx(TIdev)
  Dim HumidIndoors As Double = hs.DeviceValueEx(RhIdev)

  Dim TempOutdoors  As Double = hs.DeviceValueEx(TOdev)
  Dim HumidOutdoors As Double = hs.DeviceValueEx(RhOdev)

  ' Indoors calculations
  Dim DewPtAlphaIndoors As Double = (cA * TempIndoors) / (cB + TempIndoors) + Math.Log(HumidIndoors / 100)
  Dim DPB                As Double = (cB * DewPtAlphaIndoors) / (cA - DewPtAlphaIndoors)
  Dim DewPointIndoors   As Double = Math.Round(DPB, 2)
  Logging(LogID, "debug", "Dewpoint Indoors: " & DewPointIndoors & " (" & TempIndoors & "°C / " & HumidIndoors & "% Rh)")

  ' Outdoor calculations
  Dim DewPtAlphaOutdoor  As Double = (cA * TempOutdoors) / (cB + TempOutdoors) + Math.Log(HumidOutdoors / 100)
  Dim DPO                As Double = (cB * DewPtAlphaOutdoor) / (cA - DewPtAlphaOutdoor)
  Dim DewPointOutdoor    As Double = Math.Round(DPO, 2)
  Logging(LogID, "debug", "Dewpoint Outdoor: " & DewPointOutdoor & " (" & TempOutdoors & "°C / " & HumidOutdoors & "% Rh)")

  ' Lower is better!
  ' If Outdoor Dewpoint is lower the Indoors DP - start the fan goddamit!
  Dim Advice As String
  if ( DewPointOutdoor < DewPointIndoors ) Then
    hs.SetDeviceValueByRef(statusDev, 100, True)
    Logging(LogID, "info", "Start Ventilation fan")
    Advice = "Start fan"
  Else
    hs.SetDeviceValueByRef(statusDev, 0, True)
    Logging(LogID, "info", "Stop Ventilation fan")
    Advice = "Stop fan"
  End If
  Dim devString AS String = Advice & " (DPo: " & DewPointOutdoor & "°C - " & "DPb: " & DewPointIndoors & "°C)"
  hs.SetDevicestring(statusDev, CStr(devString), True)

  ' Logging-to-file stuff...
  If ( LogToFile ) Then
    Dim Timestamp As String  = DateTime.Now.ToString("HH:mm:ss")
    Dim Datestamp As String  = DateTime.Now.ToString("yyyy-MM-dd")
    If System.IO.File.Exists(LogFile) Then
      Dim sw As New System.IO.StreamWriter(Logfile, True)
      sw.WriteLine(Datestamp & "," & Timestamp & "," & _
                   DewPointOutdoor & "," & DewPointIndoors & "," & _
                   TempOutdoors & "," & HumidOutdoors & "," & _
                   TempIndoors & "," & HumidIndoors)
      sw.Close()
    Else
      Logging(LogID, "warn", "Log file does not exist")
    End If
  End IF

End Sub

' Routine for writing to the log
Sub Logging(ByVal LogID As String, ByVal msgType As String, ByVal msg As String)
  Dim msgComplete As String
  Dim writetolog As Boolean = False

  Select Case msgType
    Case  "info"
      If GlobalVars.infoLog Then
        msgComplete = "Info: " & msg
        writetolog = True
      End If

    Case  "debug"
      If GlobalVars.debugLog Then
        msgComplete = "Debug: " & msg
        writetolog = True
      End If

    Case  "warn"
      If GlobalVars.warnLog Then
        msgComplete = "Warning: " & msg
        writetolog = True
      End If

    Case Else
      msgComplete = "Msgtype '" & msgType & "' undefined"
      writetolog = True
  End Select

  If writetolog Then hs.Writelog (LogID, msgComplete)

End Sub

' That's all folks!

 

 

[HSv]

En liten oppdatering:

For min del ser det faktisk ut til at det hjelper å starte en vifte i tillegg til avfukteren, når duggpunkt utendørs er lavere enn innendørs.

Og det er faktisk overraskende ofte - selv i Stavanger om høsten. Men det sier kanskje mer om fuktnivået i kjelleren min...
Jeg blåser uteluften inn.

 

Men...

Det er utrolig mange faktorer som spiller inn så det er vanskelig å komme med bastante konklusjoner.
Men så lenge magefølelsen og grafene mine indikerer at det hjelper så fortsetter jeg å kjøre med denne løsningen

[Moskus]

8 minutter siden, HSv skrev:

Og det er faktisk overraskende ofte - selv i Stavanger om høsten. Men det sier kanskje mer om fuktnivået i kjelleren min...

Tror nok den siste setningen er veldig gjeldende, ja.

 

Før vi bygget om, tørket vi klær i kjelleren, og selv da tviler jeg på at det ville hatt særlig for seg. Men i "tørkegangen" var det bra naturlig ventilasjon via luftekanal i pipa, samt avfukter.

[HSv]

Vel - nå gikk jeg fra å tro til å være ganske overbevist om at det hjelper - i akkurat mitt tilfelle.
Om det er andre som har lyst å få noen tall på sin tro, i sitt tilfelle, så er scriptet fritt tilgjengelig.
Og for de som ikke vil ha tall så er det jo bare å la være ?

 

Det vil uansett være interessant for meg å høre andres erfaringer her.

 

Forøvrig - viften jeg bruker er denne, montert over en luftekanal i kjellermuren:

https://www.kjell.com/no/produkter/elektro-og-verktoy/elektronikk/electromechanics/fans/230-v/aksialvifte-230-v-120-mm-p36208

[Moskus]

Synes det var kult, jeg. Skal knabbe scriptet ditt til garasjen.

 

Men det må være lov å være overrasket over fuktnivået i kjelleren din likevel.  

En "kvalifisert gjetning" er nå likevel en gjetning. Selv om den bygger på erfaring og andre fagfolks uttalelser, betyr det ikke at man har all nødvendig input. 

[HSv]

Jeg ser den ?
Det vil bli spennende å se dine resultater i et mer moderne bygg enn mitt. Det ser ut til at @berland gjør noe lignende som det du tenker på i tråden referert til over her.

[Moskus]

Vel, garasjen er ute, så om noe er det vel enda verre i den enn i kjelleren din.  

[Gjelsvik]

On 20/09/2019 at 10:53, HSv said:

Vel - nå gikk jeg fra å tro til å være ganske overbevist om at det hjelper - i akkurat mitt tilfelle.
Om det er andre som har lyst å få noen tall på sin tro, i sitt tilfelle, så er scriptet fritt tilgjengelig.
Og for de som ikke vil ha tall så er det jo bare å la være ?

 

Det vil uansett være interessant for meg å høre andres erfaringer her.

 

Forøvrig - viften jeg bruker er denne, montert over en luftekanal i kjellermuren:

https://www.kjell.com/no/produkter/elektro-og-verktoy/elektronikk/electromechanics/fans/230-v/aksialvifte-230-v-120-mm-p36208

 

Kommer til å stjele scriptet ditt.

Jeg har kun skummet igjennom det, men sånn jeg fortstår det så trenger jeg å vite 4 forskjellige verdier. Temp ute/inne og RH ute/inne?

Jeg har i bestilling noen temp/fukt sensorer fra xiaomi, men disse tror jeg ikke er OK for  utendørs bruk. Kan jeg spørre hvor du henter dette fra ? (yr.no/met.no?)

 

Hva bruker du til å styre viften med? Er den koblet i stikk kontakt med en on/off, eller koblet fast i en boks?

 

Jeg har også bestilt en avfukter, som kommer til å stå å kjøre der nede, siden den skal kobles til sluk så blir den stående i vaskerommet. Og vaskerommet er som regel avstengt med en dør. Så jeg kommer til å kjøpe flere av disse viftene og lage hull i veggene til rommet som vaskerommet grenser til. Regner med at det er en smal sak å skrive om scriptet til å kunne beregne hvorvidt luften i vaskerommet er tørrere en de andre rommene, og deretter styre hvilke av viftene som skal gå.

[HSv]

Inne bruker jeg noen av disse:

https://www.kjell.com/no/produkter/elektro-og-verktoy/smarte-hjem/zigbee/aqara-termometer-og-hygrometer-p51358
Fås fra ebay/Kina for ca 100,- per stykk.

Jeg tester også noen av de utendørs under tak.

Utendørs ellers bruker jeg min egen og naboers netatmo, samt en Multisensor 6.

Jeg har script som kan ta input fra flere HomeSeer devicer, regne ut snitttet av disse og skrive det til et virtuelt device.

Dette virtuelle devicet bruker jeg da igjen som input for å regne ut duggpunkt.

 

Jeg tror ikke du trenger være rakettforsker for å skrive om / lage et nytt script sånn som du beskriver.

 

Jeg bruker denne til å styre viften

https://www.eldirekte.no/oomi-bryter-rele-for-innfelling/cat-p/c/p10643381

 

Om du heller bruker en plug-in type så slipper du vel elektriker ?

 

 

[Gjelsvik]

Det er de xiaomi aqara sensorene jeg også har på vei fra kina nå.

plug-in brytere har jeg liggende, så da er det vel nesten innafor å koble en lampettledning på vifta..

 

Må bare få tenkt igjennom luftflyten i underetasjen. Alle rom har sine lufteventiler her, men kun ett rom har sluk og mulighet til avfukter. Så tanken var å tørke luften i dette rommet så mye som mulig, og sirkulere den videre rundt i de andre rommene etterpå. Om alle rom har åpne ventiler mot uteluft så blir det en evig kamp som avfukteren ikke klarer å vinne (?) Dreneringen er ny nå i år, og muren er ekstraisolert utvendig under bakkeplan, så alt skal ligge til rette for en tørr kjeller. Allikevel måler jeg nå oppunder 70% RH i noen av rommene hvor leieboer er dårligst på å ha ventilasjonslukene åpne.